GroupBox and ContainerControl need method to find nested control by name or tag

DrScott

The current method of finding a control within a GroupBox (or ContainerControl) is insufficient if they contain many controls. It requires the programmer to keep a list of the indices of every control added as they are added, one by one. This will definitely be a problem if the programmer wants to add several existing controls to a new GroupBox (or ContainerControl) by dragging them all at once into it -- the indices of the controls would be unknown to the programmer. It also makes the code harder to understand unless an enumeration is created with all of the indices of the controls.

Please add a method to retrieve a particular control in a GroupBox (or ContainerControl) by name or, if that is not easily done, add a "tag" member to each control so that controls can be searched by tag.

rgb

Hi @DrScott

You add this method for the moment:

create method named "FindControl(x as String) As Boolean

code text:

If Me.CountControls() > 0 Then

For i As Integer = 0 To Me.CountControls() - 1

Var b As Control = Me.ControlAt(i)

If b.Name = x Then

Return True

End If

Next i

End If

Return False

DrScott

rgb

Thank you. That’s a good idea.

Garry

A good workaround @rgb, thanks.

I've added a framework mechanism to solve this for the next release: https://feedback.objo.dev/feature/293

Richard_And_Trisha

how do I use FindControl?? wasn't very clear in the documentation

rgb

Richard_And_Trisha

Hi,
FindControl is a method in begin of the thread
Can't help you, for the moment you can't get subcontrols list for PagePanel and TabPanel

The unique solution for you are:
Add "Opening" event for each control in your window and add to array and parse after when you want search control

Richard_And_Trisha

try the code above , and got error on Me.CountControls and Me.ControlAt

If Me.CountControls() > 0 Then
For i As Integer = 0 To Me.CountControls() - 1
Var b As Control = Me.ControlAt(i)
If b.Name = x Then
Return True
End If
Next i
End If
Return False

rgb

Richard_And_Trisha

Try remplace "Me" by "Self"
If doesn't
hit:

print(me,self)

for known what is type of class

Richard_And_Trisha

rgb just try changing me and self and still got error actually on CountControls and ControlAt

[Error] frmCollection.do_FindControl Line 1: Type 'frmCollection' has no member 'CountControls'.
[Error] frmCollection.do_FindControl Line 2: Type 'frmCollection' has no member 'CountControls'.
[Error] frmCollection.do_FindControl Line 3: Type 'frmCollection' has no member 'ControlAt'.

rgb

Richard_And_Trisha

what is type of frmCollection ?

Garry

The code near the beginning of this thread was a suggested workaround from before this feature shipped. CountControls() and ControlAt() are not Objo methods, which is why that code produces errors.

Since Objo Studio v26.5.8, call FindControl() directly on a GroupBox or ContainerControl:

Var control As Control = GroupBox1.FindControl("TextField1")

If control <> Nothing And control IsA TextField Then
    Var field As TextField = TextField(control)
    field.Text = "Found it"
End If

FindControl() searches recursively and returns the first control with the specified name, or Nothing if none is found. There is also FindControlByTag(). ScrollBox supports both methods as well.

The recursive search can pass through nested ContainerControls, GroupBoxes, ScrollBoxes, PagePanels and TabPanels. However, PagePanel and TabPanel do not currently expose FindControl() themselves. If your search needs to begin at one of those controls, please describe your layout and what you’re trying to find.

Richard_And_Trisha

Garry is there anything to loop through each control for page panel and tab pane using FindControl()l???

I have a TabPanel with 2 tab with a few labels and textfields, some textarea and some combobox on the first tab.

I an array of fields and value from sqlite db. I want to basically match up the data field with the controls


While rs.MoveToNextRow()

For c As Integer = 0 To rs.ColumnCount - 1
a_fields.Append(rs.ColumnName(c).ToString())
a_values.Append(rs.ColumnAt(c).StringValue)
Next
Wend
rs.Close()

Var xFieldNum As Integer
For x As Integer = 0 To a_fields.Count - 1

xFieldNum = a_fields.IndexOf(a_controls[x].Name)
Var control As Control = TabPanel1.FindControl(a_fields[x])

If control <> Nothing And control IsA TextField Then
Var field As TextField = TextField(control)
field.Text = a_values[xFieldNum]
End If
Next

Richard_And_Trisha

or the other way is defining the control name which has the same name as the field name in the db. something like looping through the array, then compare the name of control with the a_fields array and then get the data from a_values.

the problem I have is getting the control name in the tab panel

Var a_controls() As Control = [Reference, ClientRef, Field1, Field2, Field3, Field4, Field5, Field6, Field7, Field8, Field9, Field10, Field11, Field12, Status]

Richard_And_Trisha

I got it work if I setup the a_controls with the various fields.

I manage to get the data to show up with the following code

Var a_controls() As Control = [Reference, ClientRef, Field1, Field2, Field3, Field4, Field5, Field6, Field7, Field8, Field9, Field10, Field11, Field12, Status]

Var xFieldNum As Integer
Var x_field As String

For x As Integer = 0 To a_controls.Count - 1
xFieldNum = a_fields.IndexOf(a_controls[x].Name)
If a_controls[x] IsA TextField Then
Var tf As TextField = TextField(a_controls[x])
tf.Text = a_values[xFieldNum]
ElseIf a_controls[x] IsA TextArea Then
Var ta As TextArea = TextArea(a_controls[x])
ta.Text = a_values[xFieldNum]
ElseIf a_controls[x] IsA ComboBox Then
Var cbo As ComboBox = ComboBox(a_controls[x])
cbo.Text = a_values[xFieldNum]
End If
Next

so it would be wonderful It I can loop through all the controls that is NOT button or label and assign each to to a_controls array

Richard_And_Trisha

was trying to use the following code to set up the a_controls array but the Me.Controls().Count only show 2 which is tab panel and the groupbox (my sidebar)

Var a_controls() As Control
print(Me.Controls().Count.ToString())
For x As Integer = 0 To Me.Controls().Count - 1
If Me.Controls()[x] IsA TextField Then
Var tf As TextField = TextField(Me.Controls()[x])
a_controls.Append(tf)
ElseIf Me.Controls()[x] IsA TextArea Then
Var ta As TextArea = TextArea(Me.Controls()[x])
a_controls.Append(ta)
ElseIf Me.Controls()[x] IsA ComboBox Then
Var cbo As ComboBox = ComboBox(Me.Controls()[x])
a_controls.Append(cbo)
End If
Next

Garry

Me.Controls() returning 2 is expected: it returns only the controls directly on the Window—in this case, the TabPanel and `GroupBox—not their descendants.

I’ve now added the missing APIs for the next release: https://feedback.objo.dev/feature/1209

TabPanel.Controls(tabIndex) returns the direct controls on a tab.
TabPanel.FindControl(name) searches recursively across every tab.
TabPanel.FindControlByTag(tag) does the same by tag.
PagePanel now has the equivalent APIs.

Because your database column names match your control names, you will not need to build a_controls():

For x As Integer = 0 To a_fields.Count - 1
    Var control As Control = TabPanel1.FindControl(a_fields[x])

    If control <> Nothing Then
        If control IsA TextField Then
            Var field As TextField = TextField(control)
            field.Text = a_values[x]
        ElseIf control IsA TextArea Then
            Var area As TextArea = TextArea(control)
            area.Text = a_values[x]
        ElseIf control IsA ComboBox Then
            Var combo As ComboBox = ComboBox(control)
            combo.Text = a_values[x]
        End If
    End If
Next

FindControl() compares names case-insensitively and searches through nested containers as well.

If you specifically need to enumerate the direct controls on every tab, you will also be able to do this:

For tabIndex As Integer = 0 To TabPanel1.TabCount - 1
    For Each control As Control In TabPanel1.Controls(tabIndex)
        If control IsA TextField Or _
           control IsA TextArea Or _
           control IsA ComboBox Then
            a_controls.Append(control)
        End If
    Next
Next

Until that release is installed, your explicitly populated a_controls array remains the appropriate workaround.

Richard_And_Trisha

In future, can I loop thorough all the control and if encounter a tab panel or page panel or any other thing, drill down with the code you mentioned above, so a few for-next loop one inside another??

Garry

Yes, once the next release is out and installed. However, you should not use a fixed number of nested For loops, because that would only handle a particular nesting depth.

For your database example, FindControl() already performs the recursive drilling for you. Calling:

Var control As Control = TabPanel1.FindControl(a_fields[x])

searches every tab and continues through nested TabPanel, PagePanel, ContainerControl, GroupBox and ScrollBox controls.

If you later need to enumerate every control rather than find one by name, use a recursive helper. Each Controls() call returns the direct children, and the helper can call itself whenever it encounters another container. That will work regardless of how deeply the controls are nested.

Richard_And_Trisha

sound like exactly what I need.. thanks